MODEL ov9 
 
! INDEKSER 
! t - tidsperioder t=1...TMAX 
! i,j - industri (Manpower ikke med) i,j=1...IMAX 
! n - ant. m†lfunksjoner n=1...NMAX 
 
TABLES 
 
 DIMM(3)        ! Dimensjonstabell som inneholder maksimalverdi p† de3 indeksene 
 
!                               Leser dimensjonstabellen for indeksene 
 
DISKDATA 
 
 DIMM(1) =  ov9.dim 
 
!       Setter nytt navn p† maksimalverdiene av indeksene 
 
LET TMAX = DIMM(1) 
LET  IMAX = DIMM(2) 
LET  NMAX = DIMM(3) 
 
!       Definerer tabeller for data som er indeksspesifiserte 
 
TABLES 
 
!       Data som skal leses direkte fra andre filer 
 
 OMAN(IMAX)             ! mengde manpower input for en output i industri i 
 CMAN(IMAX)             ! mengde manpower input for en kapasitets°kning i industri i 
 DEMAND(IMAX)   ! †rlig ettersp°rsel for industri i (eksogen) 
 INKAP(IMAX)            ! initiell kapasitet for industri i 
 PKOF(IMAX,IMAX)  ! mengde input fra industri i for produksjon av en enhet i industri j 
 PKAP(IMAX,IMAX)        ! mengde input fra industri i for kapasitets°kning i industri j 
 DELTA(NMAX)            ! indikator for valg av m†lfunksjon (binµrvariabel) 
 INLAGER(IMAX)  ! lager i †r 0 
 
DISKDATA 
 
 OMAN(1)        = ov9.oma 
 CMAN(1)        = ov9.cma 
 DEMAND(1)      = ov9.dem 
 INKAP(1)       = ov9.ink 
 PKOF(1,1)      = ov9.pko 
 PKAP(1,1)      = ov9.pka 
 DELTA(1)       = ov9.del 
 INLAGER(1)     = ov9.inl 
 
 
VARIABLES 
 
 y (i=1:IMAX,t=2:TMAX) ! ekstra prod.kapasitet for industri i som blir effektiv i †r t. 
 x (i=1:IMAX,t=1:TMAX+2)        ! total output for industri i †r t. 
 s (i=1:IMAX,t=1:TMAX+2)        ! lagerniv† for industri i ved begynnelsen av †r t. 
 
CONSTRAINTS 
 
 maal:  SUM(t=2:TMAX,i=1:IMAX | DELTA(1) .eq. 1) y(i,t) & 
	+ SUM(i=1:IMAX | DELTA(1) .eq. 1) INKAP(i) & 
	+ SUM(t=TMAX-1:TMAX,i=1:IMAX | DELTA(2) .eq. 1) x(i,t) & 
        + SUM(t=1:TMAX, i=1:IMAX | DELTA(3) .eq. 1) OMAN(i) * x(i,t+1) & 
        + SUM(t=1:TMAX-2, i=1:IMAX | DELTA(3) .eq. 1) CMAN(i) * y(i,t+2) $ 
 
 prodkap(i=1:IMAX,t=1:TMAX+2): x(i,t) < INKAP(i) + SUM(l=2:TMAX | l .le. t) y(i,l) 
 
 manpower(t=1:TMAX | DELTA(3) .eq. 0): SUM(i=1:IMAX ) OMAN(i)* x(i,t+1) &
   + SUM(i=1:IMAX | t .le. TMAX-2) CMAN(i)*y(i,t+2)   <  470 

 totalinput(i=1:IMAX,t=1:TMAX+2): SUM(j=1:IMAX | t .le. TMAX+1) PKOF(i,j)*x(j,t+1) & 
			+ SUM(j=1:IMAX | t .le. TMAX-2) PKAP(i,j)*y(j,t+2) & 
			< x(i,t) + s(i,t) - SUM(| t .le.  TMAX+1) s(i,t+1)  & 
			- SUM(|DELTA (2) .ne. 1) DEMAND(i) 

! hs(i=1:IMAX,t=1:TMAX+2): x(i,t) + s(i,t) - SUM(| t .le.  TMAX+1) s(i,t+1) &
!			 - SUM(|DELTA (2) .ne. 1) DEMAND(i) > 0
 
 inputaar0(i=1:IMAX): SUM(j=1:IMAX) PKOF(i,j)*x(j,1) & 
			+ SUM(j=1:IMAX) PKAP(i,j)*y(j,2) & 
			< INLAGER(i) - s(i,1) 
 
 sl1(i=1:IMAX): s(i,TMAX+2) - s(i,TMAX+1) = 0 
 
 sl2(i=1:IMAX): s(i,TMAX+1) - s(i,TMAX) = 0 

GENERATE